{*************************************************************************
 *                                                                       *
 *                       Pogromcy Algorytmów 2004                        * 
 *                                                                       *
 *   Rozwiązanie zadania: Julka                                          *
 *   Plik:                jul.pas                                        *
 *   Autor:               Krzysztof Diks                                 *
 *************************************************************************}

type
  liczba = array[0..100] of integer; {liczba[i] \in [0..9]}
	
procedure ini(var l : liczba);
var
  i : integer;
begin
  for i := 0 to 100 do l[i] := 0
end;			
	
procedure dodaj(l1, l2: liczba; var s : liczba);
var
  i, przen : integer;
begin
	przen := 0;
	for i := 0 to 100 do
	begin
	  s[i] := (l1[i] + l2[i] + przen) mod 10;
		przen := (l1[i] + l2[i] + przen) div 10
	end
end;

procedure odejmij(l1, l2: liczba; var s : liczba);
{ l1 >= l2}
var
  i : integer;
begin
  for i := 0 to 100 do
	begin
	  if l1[i] < l2[i] then
		begin
		  l1[i] := l1[i] + 10; l1[i+1] := l1[i+1] - 1
		end;
		s[i] := l1[i] - l2[i]	   
	end
end;				
			
procedure dziel_przez_dwa(var s : liczba);
{s parzysta}
var
  i : integer;
begin
  for i := 100 downto 0 do
	begin
	  if odd(s[i]) then 
		  s[i - 1] := 10 + s[i - 1];
	  s[i] := s[i] div 2
	end	
end;					


procedure wczytaj(var s : liczba);
var
  i,j : integer;
	p : liczba;
	zn : char;
begin
  i := -1;
	while not eoln do
	begin
	  i := i + 1;
		read(zn);
		p[i] := ord(zn) - ord('0')
	end;
	j := -1;
	while i >= 0 do
	begin
	  j := j + 1;
	  s[j] := p[i];
		i := i - 1
	end;
	readln
end;		 	  	

procedure wypisz(s : liczba);
var
  i : integer;
begin
  i := 100;
	while s[i] = 0 do i := i - 1;
	while i >= 0 do
	begin
	  write(s[i]);
		i := i - 1
	end;	
	writeln
end;			

var
  a, b, x, y : liczba; 
begin
  wczytaj(a); wczytaj(b);
	dodaj(a,b,x); dziel_przez_dwa(x);
	odejmij(a,b,y); dziel_przez_dwa(y);
	wypisz(x); wypisz(y)
end.				       
	