{*************************************************************************
 *                                                                       *
 *                       Pogromcy Algorytmów 2004                        * 
 *                                                                       *
 *   Rozwiązanie zadania: Dyzio                                          *
 *   Plik:                dyz.pas                                        *
 *   Autor:               Krzysztof Diks                                 *
 *************************************************************************}

{ Rozwiazanie wzorcowe dla zadania Dyzio.
  Napis 0-1, to kod obchodzenia drzewa binarnego
  metoda preorder. Jedynki odpowiadaja wezlom wewnetrznym
  (z co najmniej 1 synem), a zera wezlom zewnetrznym - bez synow.
  Kazdy wezel zewnetrzny (0) odpowiada jednemu, niepodzielnemu kawalkowi
  sznurka. Naszym celem jest znalezienie pierwszego 0 na najwiekszej glebokosci
  w drzewie. }

const
  max_dl = 20000;

var
  max_gl, poprz_1 : integer; {dotychczas osiagnieta maksymalna glebokosc, oraz
                          liczba poprzedzajacych ja 1-nek}
  
														
  ile_1 : integer; {ile bylo juz 1-nek}
	
  kod : array [1..max_dl] of char; {kod drzewa, pozycje to numery wezlow w porzadku
                        preorder}
	dl : integer; {dlugosc kodu}											
  odw: integer; {odw+1 jest pierwszym wezlem, w ktorym jeszcze nie bylismy}
  gl : integer; {aktualna glebokosc na jakiej sie znajdujemy}


procedure obejdz_drzewo;
{wchodzimy do pierwszego, w ktorym nie bylismy}
begin
  odw := odw + 1;
  gl := gl + 1;  
  if kod[odw] = '1' then
  {wezel wewnetrzny}
  begin
	  ile_1 := ile_1 + 1;
    obejdz_drzewo; {obejscie lewego poddrzewa}
    obejdz_drzewo {obejscie prawego poddrzewa}
  end 
	else
  {wezel zewnetrzny}
    if gl >  max_gl then
    begin
      max_gl := gl; 
      poprz_1 := ile_1
    end;
		
  gl := gl - 1 {powrot}
end;

var
  i : integer;

begin
  readln(dl);
	for i := 1 to dl do
    read(kod[i]);
  odw := 0; gl := -1; max_gl := -1; ile_1 := 0; poprz_1 := 0;
  obejdz_drzewo;
  writeln(poprz_1)
end.
      
 